Začneme týmto jednoduchým príkladom. Chceme zmazať obrazovku v textovom móde a využijeme na to priamy prístup k nej. Obrazovka začína na B800:0000h a má 80 stĺpcov a 25 riadkov (v základnom textovom móde) po dvoch bajtoch. Prvý je ASCII kód znaku, druhý je farba znaku.

[BITS 16]
[ORG 0x0100]
[SECTION .text]

MOV AX,0B800H ;hexadecimálne číslo musí začínať číslicou, aby nebolo zamýlené s názvom návestia, preto ho treba zapísať ako 0B800h a nie B800h
MOV ES,AX ;segmentový register ES možno napĺňať len cez AX
MOV CX,80*25
MOV AX,7*256+' ' ;farbou 7 (biela) "vymaz" obrazovku medzerami
REP STOSW

MOV AX,4C00h
INT 21h

    Ďalší príklad vypíše pevne zvolené číslo v pevne zvolenej sústave (v rozsahu 2 - dvojková - až 16 - hexidecimálna). Na výpis využíva službu DOSu.

[BITS 16]
[ORG 0x0100]

[SECTION .text]

MOV AX,12345 ;vypisované číslo v rozsahu 0 až 65535
MOV BL,16 ;základ sústavy v rozsahu 2 až 16

MOV DI,16 ;číslo budeme zapisovať od konca - od najnižšej čílice

dalej:
DEC DI ;ďalšia číslica
XOR DX,DX ;DX<-0
DIV BX ;do DX ďalšia číslica
MOV SI,DX
MOV DL,[SI+cislice] ;zisti znak pre dané číslo...
MOV [DI+vypis],DL ;...a vypíš ho
AND AX,AX
JNZ dalej ;znova, dokým nebude AX=0, tzn. dokým nevypíšeme všetky číslice

MOV DX,text ;do DX adresu prvého textu
MOV AH,09h ;číslo služby...
INT 21h ;...určenej na vypisovanie textu
MOV DX,vypis
ADD DX,DI ;výpis čísla začneme od prvej - najvyššej, teda naposledy zapísanej číslice
MOV AH,09h
INT 21h

MOV AX,4C00h
INT 21h

[SECTION .data] ;tak takto sa definuje oblasť premenných

cislice DB '0123456789ABCDEF' ;zoznam znakov číslic
text DB 'Cislo = $' ;vypisovaný text ukončený znakom $
vypis TIMES 16 DB 0
DB '$' ;najviac šestnásťznakové číslo, ktoré bude vypísané - cez direktívu TIMES sa definuje poľe z rovnakých údajov jednoduchšie

    Tento program pracuje s číslom získaného zo vstupu (z klávesnice, v prostredí NASMIDE treba vstup zadať v menu cez položku parameters), v rozsahu slova (0 až 65535). Hľadá jeho odmocninou v podstate metódou pokus - omyl. Skúša postupne nastavovať jednotlivé bity hľadaného výsledku (od najvyššieho) a tak toto číslo umocní. Ak je mocnina väčšia, nastavovaný bit treba opäť vynulovať.

[BITS 16]
[ORG 0x0100]

[SECTION .text]

MOV DX,vstup ;zo štandardného vstupu prepíš...
MOV CX,7 ;...sedem znakov, keďže dva z nich budú znamenať ukončenie riadku, teda stlačenie enteru (0Dh, 0Ah)...
MOV BX,0 ;...do pamäte od miesta návestia vstup
MOV AH,3Fh
INT 21h

SUB AX,2 ;v AX je počet znakov zo vstupu, no treba odstrániť znak enter
OR AX,AX
JZ koniec ;ak nie je vstup, skonči
MOV CX,AX ;do CX počet znakov
MOV DI,vstup
MOV BX,10 ;ideme previesť vstup v desiatkovej sústave do registra AX
XOR AX,AX
XOR DH,DH ;vynuluj AX a DH
testuj:
MUL BX ;vynásob aktuálny výsledok desiatimi
MOV DL,[DI] ;prečítaj ďalší znak
SUB DL,'0' ;zmeň ASCII znak na číslo 0 až 9
INC DI ;presuň ukazovateľ na ďalší znak
CMP DL,0
JC koniec ;ak nie je číslo v rozsahu 0 až 9, tak skonči
CMP DL,10
JNC koniec
ADD AX,DX ;pripočítaj čílicu k aktuálnemu výsledku
LOOP testuj ;t.j. SUB CX,1 a JNZ testuj - jednoduchý cyklus
JMP pokracuj

koniec:
MOV AX,4C00h
INT 21h ;bol nevhodný vstup - skonči

pokracuj:
MOV CX,AX ;do CX odmocňované číslo
MOV BL,10000000b ;začneme najvyšším bitom
XOR BH,BH ;BH<-0
MOV DL,2

hladaj:
ADD BH,BL ;pokusne pripočítaj skúmaný bit
MOV AL,BH
MUL AL ;umocni predpokladanú odmocninu...
CMP CX,AX ;...a porovnaj ju s odmocňovaným číslom
JNC dobre
SUB BH,BL ;trochu sme to prešvihli, odpočítaj ten bit späť
dobre:
MOV AL,BL ;ak je všetko v poriadku...
XOR AH,AH
DIV DL
MOV BL,AL ;posuň BL na ďalší bit - vydeľ ho dvoma a zarotuje doprava
OR AL,AL
JNZ hladaj ;ak sme nepreskúmali všetky bity, pokračuj

MOV AL,BH
MUL AL
SUB CX,AX ;ešte raz výsledné číslo umocni a získaj zvyšok po delení
MOV AL,BH
XOR AH,AH

MOV BX,10
MOV DI,3

dalej1: ;výpis registra AX - výsledku - procedúrou ako v programe výpis čísla
DEC DI
XOR DX,DX
DIV BX
MOV SI,DX
MOV DL,[SI+cislice]
MOV [DI+vypis1],DL
AND AX,AX
JNZ dalej1

MOV DX,text1
MOV AH,09h
INT 21h
MOV DX,vypis1
ADD DX,DI
MOV AH,09h
INT 21h

MOV DI,3
MOV AX,CX

dalej2: ;výpis registra CX - zvyšku - podobne
DEC DI
XOR DX,DX
DIV BX
MOV SI,DX
MOV DL,[SI+cislice]
MOV [DI+vypis2],DL
AND AX,AX
JNZ dalej2

MOV DX,text2
MOV AH,09h
INT 21h
MOV DX,vypis2
ADD DX,DI
MOV AH,09h
INT 21h

MOV AX,4C00h
INT 21h

[SECTION .data]

vstup TIMES 7 DB 0 ;miesto pre vstup z klávesnice
cislice DB '0123456789' ;znaky a texty na výpis ako v programe výpis čísla
text1 DB 'Odmocnina = $'
vypis1 TIMES 3 DB 0
DB '$'
text2 DB ', zvysok = $'
vypis2 TIMES 3 DB 0
DB '.$'

    Posledný program je pokus o šetrič obrazovky. Vypisuje štyridsať znakov "usmievavej tváre" (znak 01h ASCII) a pohybuje nimi rôznymi smermi. Ak nejaké "vypadne" z obrazovky, program vygeneruje ďalší znak.